ADO 表示

レコードセットからデータを表示する最も一般的な方法は、HTML テーブルにデータを表示することです。

例

レコードを表示
まずデータベース接続を設定し、その後レコードセットを作成し、HTML にデータを表示する方法
HTML テーブルにレコードを表示
データテーブルのデータを HTML テーブルに表示する方法
HTML テーブルに見出しを追加
HTML テーブルに見出しを追加して、読みやすさを向上させる方法
HTML テーブルに色を追加
HTML テーブルに色を追加して、見た目をより魅力的にする方法

フィールド名とフィールドの値を表示

「Northwind」という名前のデータベースがあり、"Customers" テーブルのデータを表示したいと思っています（ファイルを保存する際には .asp エクステンションを使用してください）：

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

フィールド名とフィールドの値を HTML テーブルに表示

以下のコードを使用して、"Customers" テーブルのデータを HTML テーブルに表示することもできます：

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

HTML テーブルに見出しを追加

この HTML テーブルに見出しを追加したいと思います。これにより、読みやすくなります：

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>