Peningkatan Skrip dengan GetString() ADO

Gunakan metode GetString() untuk mempercepat skrip ASP Anda (gantikan Response.Write berbaris).

Contoh

Penggunaan GetString()
Bagaimana menggunakan GetString() untuk menampilkan data dalam kumpulan rekaman tabel HTML.

Multi-line Response.Write

Contoh di bawah ini menunjukkan cara menampilkan hasil query database dalam tabel HTML:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
      <td><%Response.Write(rs.fields("Companyname"))%></td>
      <td><%Response.Write(rs.fields("Contactname"))%></td>
   </tr>
<%rs.MoveNext
loop%>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

Untuk kueri besar, hal ini akan menambah waktu pemrosesan skrip, karena server harus menangani banyak perintah Response.Write.

Penyelesaian adalah untuk membuat seluruh string, dari <table> hingga </table>, dan kemudian mengekspornya - hanya sekali Response.Write.

Metode GetString()

Metode GetString() memberikan kemampuan untuk menampilkan semua string hanya dengan sekali Response.Write, bahkan tanpa kode do..loop dan pengujian kondisi untuk mengecek apakah kumpulan catatan berada di EOF.

Sintaks

str = rs.GetString(format, rows, coldel, rowdel, nullexpr)

Untuk membuat tabel HTML dari data yang datang dari kumpulan catatan, kami hanya perlu menggunakan tiga parameter di atas (semua parameter adalah pilihan):

  • coldel - Digunakan sebagai pemisah kolom HTML
  • rowdel - Digunakan sebagai pemisah baris HTML
  • nullexpr - HTML yang digunakan saat kolom kosong

Keterangan:Metode GetString() adalah fitur ADO 2.0. Anda dapat mengunduh ADO 2.0 dari alamat di bawah ini:http://www.microsoft.com/data/download.htm

Dalam contoh di bawah ini, kita akan menggunakan metode GetString() untuk menyimpan kumpulan catatan sebagai string:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
str=rs.GetString(,,"</td><td>","</td></tr><tr><td>"," ")
%>
<table border="1" width="100%">
  <tr>
    <td><%Response.Write(str)%></td>
  </tr>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

Variabel di atas str mengandung string seluruh kolom dan baris yang dihasilkan oleh pernyataan SELECT. Antara setiap kolom akan muncul </td><td> dan antara setiap baris akan muncul </td></tr><tr><td>. Dengan hanya menggunakan Response.Write sekali, kami mendapatkan HTML yang dibutuhkan.