Tampilan ADO

Metode paling sering digunakan untuk menampilkan data dari recordset adalah menampilkan data di dalam tabel HTML.

Contoh

Tampilkan rekaman
Bagaimana untuk pertama kali membuat koneksi database, lalu membuat recordset, dan kemudian menampilkan data di dalam HTML.
Tampilkan rekaman di dalam tabel HTML
Bagaimana menampilkan data tabel di dalam tabel HTML.
Tambahkan judul ke tabel HTML
Bagaimana menambahkan judul ke tabel HTML untuk meningkatkan keterbacaannya.
Tambahkan warna ke tabel HTML
Bagaimana menambahkan warna ke tabel HTML untuk membuatnya menjadi lebih indah.

Tampilkan nama kolom dan nilai kolom

Kami memiliki database yang bernama "Northwind" dan ingin menampilkan data tabel "Customers" (jangan lupa untuk menyimpan berkas ini dengan ekstensi .asp):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

Tampilkan nama kolom dan nilai kolom di dalam tabel HTML

Kami juga dapat menampilkan data tabel "Customers" di dalam tabel HTML menggunakan kode di bawah ini:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

Tambahkan judul ke tabel HTML

Kami ingin menambahkan judul untuk tabel HTML ini, sehingga ia menjadi lebih mudah dipahami:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>