ADO Accelerate Script via GetString()

Gumamit ng method na GetString() upang mapabilis ang iyong ASP script (sa halip ng maraming linya ng Response.Write).

Halimbawa

Gamitin ang GetString()
Paano gamitin ang GetString() para ipakita ang data ng recordset sa HTML table.

Maraming linya ng Response.Write

Ang halimbawa na ito ay nagpapakita ng isang paraan para ipakita ang resulta ng pagkuha ng database sa HTML table:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
      <td><%Response.Write(rs.fields("Companyname"))%></td>
      <td><%Response.Write(rs.fields("Contactname"))%></td>
   </tr>
<%rs.MoveNext
loop%>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

Para sa malaking query, ganitong pagkilos ay magpahaba ng pagproseso ng script, dahil kailangan ng server na magtrabaho sa maraming command ng Response.Write.

Ang solusyon ay gumawa ng buong string mula <table> hanggang </table>, at i-output ito gamit lamang ang isang Response.Write.

Methodong GetString()

Ang methodong GetString() ay nagbibigay-daan sa amin na ipakita ang lahat ng string gamit lamang ang isang Response.Write, at hindi kailangan ng code ng do..loop at conditional testing upang suriin kung ang recordset ay nasa EOF.

Grammar

str = rs.GetString(format,rows,coldel,rowdel,nullexpr)

Upang gumawa ng isang HTML table gamit ang data mula sa recordset, kailangan lang namin ng tatlong paramter mula sa mga ito (lahat ng mga paramter ay opsyonal):

  • coldel - Ginagamit bilang tag-komadyon sa HTML
  • rowdel - Ginagamit bilang tag-apostrophe sa HTML
  • nullexpr - Ginagamit bilang HTML kapag ang linya ay walang laman

Komento:Ang methodong GetString() ay isang katangian ng ADO 2.0. Maaari mong i-download ang ADO 2.0 mula sa sumusunod na link:http://www.microsoft.com/data/download.htm

Sa mga sumusunod na halimbawa, gagamitin namin ang methodong GetString(), upang isave ang recordset bilang isang string:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
str=rs.GetString(,,"</td><td>","</td></tr><tr><td>"," ")
%>
<table border="1" width="100%">
  <tr>
    <td><%Response.Write(str)%></td>
  </tr>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

Ang variable na ito ay may nilalaman na naglalaman ng lahat ng mga column at row na ibinabalik ng SELECT statement, sa pagitan ng bawat column ay may </td><td>, at sa pagitan ng bawat row ay may </td></tr><tr><td>. Sa pamamagitan ng paggamit lamang ng Response.Write, nakakakuha kami ng kinakailangang HTML.