ADO การแสดง

วิธีที่ใช้บ่อยที่สุดในการแสดงข้อมูลจากรายชุดเพื่อแสดงข้อมูลในตาราง HTML

ตัวอย่าง

แสดงบันทึก
วิธีเริ่มต้นด้วยการสร้างการเชื่อมต่อฐานข้อมูล แล้วสร้างรายชุด และแสดงข้อมูลใน HTML
แสดงบันทึกในตาราง HTML
วิธีแสดงข้อมูลของตารางในตาราง HTML
เพิ่มหัวข้อให้กับตาราง HTML
วิธีเพิ่มหัวข้อให้กับตาราง HTML ในการที่มันจะง่ายต่อการอ่าน:
เพิ่มสีให้กับตาราง HTML
วิธีเพิ่มสีให้กับตาราง HTML ในการที่มันจะดูงดงามขึ้น:

แสดงชื่อฟิลด์และค่าฟิลด์

เรามีฐานข้อมูลชื่อ "Northwind" และเราต้องการแสดงข้อมูลของตาราง "Customers" (จำเป็นต้องบันทึกไฟล์ด้วยนามสกุล .asp):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

แสดงชื่อฟิลด์และค่าฟิลด์ในตาราง HTML

เรายังสามารถใช้โค้ดด้านล่างนี้เพื่อแสดงข้อมูลของตาราง "Customers" ในตาราง HTML:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

เพิ่มหัวข้อให้กับตาราง HTML

เราต้องการเพิ่มหัวข้อให้กับตาราง HTML นี้ เพื่อที่มันจะง่ายต่อการอ่าน:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>