ADO ప్రదర్శన

రికార్డ్సెట్ నుండి డేటాను ప్రదర్శించడానికి అత్యంత ఉపయోగించే విధానం డేటాను HTML పట్టికలో ప్రదర్శించడం.

ఉదాహరణ

రికార్డులను ప్రదర్శించండి
మొదటగా డేటాబేస్ కనెక్షన్ను సృష్టించడానికి, అప్పుడు రికార్డ్సెట్ను సృష్టించడానికి మరియు అదిలోని డేటాను HTMLలో ప్రదర్శించడానికి ఎలా.
HTML పట్టికలో రికార్డులను ప్రదర్శించండి
డేటా పట్టికలోని డేటాను HTML పట్టికలో ప్రదర్శించడానికి ఎలా.
HTML పట్టికకు శీర్షికను జోడించండి
ఎలా HTML పట్టికకు శీర్షికను జోడించి అది ఎక్కువగా చదవకపోతే అది చాలా సులభం అవుతుంది.
HTML పట్టికకు రంగును జోడించండి
ఎలా HTML పట్టికకు రంగును జోడించి అది ఎక్కువగా అలంకరించాలి.

ఫీల్డ్ పేర్లు మరియు ఫీల్డ్ విలువలను ప్రదర్శించండి

మాకు "Northwind" పేరుతో ఒక డేటాబేస్ ఉంది మరియు మేము "Customers" పట్టికలోని డేటాను ప్రదర్శించడానికి కోరుకున్నాము (ఈ ఫైల్ని .asp ఎక్స్టెన్షన్గా సేవ్ చేయండి):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

ఫీల్డ్ పేర్లు మరియు ఫీల్డ్ విలువలను ఒక HTML పట్టికలో ప్రదర్శించండి

మేము కూడా క్రింది కోడ్ ద్వారా "Customers" పట్టికలోని డేటాను HTML పట్టికలో ప్రదర్శించవచ్చు:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

HTML పట్టికకు శీర్షికను జోడించండి

ఈ HTML పట్టికలో శీర్షికను జోడించడానికి మేము కోరుకున్నాము కాబట్టి అది ఎక్కువగా చదవకపోతే అది చాలా సులభం అవుతుంది:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>