ADO display

Det mest använda sättet att visa data från en recordset är att visa data i en HTML-tabell.

Exempel

Visa poster
Hur skapar man först en databasanslutning, sedan en recordset och visar data i HTML?
Visa poster i HTML-tabell
Hur visar man data från en datatabell i en HTML-tabell?
Lägg till rubrik till HTML-tabell
Hur lägger man till en rubrik till en HTML-tabell för att göra den mer läsbar?
Lägg till färg till HTML-tabell
Hur lägger man till färg till en HTML-tabell för att göra den mer estetisk?

Visa fältnamn och fälervärden

Vi har en databas med namnet "Northwind" och vi vill visa data från tabellen "Customers" (kom ihåg att spara filen med .asp-utökning):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

Visa fältnamn och fälervärden i en HTML-tabell

Vi kan också visa data från tabellen "Customers" i en HTML-tabell med följande kod:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

Lägg till rubrik till HTML-tabell

Vi vill lägga till en rubrik till denna HTML-tabell, så att den blir lättare att läsa:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>