Exibição ADO

A maneira mais comum de exibir dados de um conjunto de registros é mostrar os dados em uma tabela HTML.

Exemplo

Exibir registros
Como primeiro criar uma conexão de banco de dados, então criar um conjunto de registros e, em seguida, exibir os dados em HTML.
Exibir registros em uma tabela HTML
Como exibir dados de um conjunto de dados em uma tabela HTML.
Adicionar título à tabela HTML
Como adicionar um título a uma tabela HTML para melhorar sua legibilidade.
Adicionar cor à tabela HTML
Como adicionar cor a uma tabela HTML para torná-la mais bonita.

Exibir nomes de campo e valores de campo

Nós temos um banco de dados chamado "Northwind" e queremos exibir os dados da tabela "Customers" (lembrando de salvar o arquivo com a extensão .asp):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

Exibir nomes de campo e valores de campo em uma tabela HTML

Também podemos usar o seguinte código para exibir os dados da tabela "Customers" em uma tabela HTML:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

Adicionar título à tabela HTML

Nós queremos adicionar um título a essa tabela HTML, para torná-la mais legível:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>