ADO Weergave

De meest gebruikte methode om gegevens van een recordset weer te geven, is het weergeven van de gegevens in een HTML-tabel.

Voorbeeld

Een record weergeven
Hoe kan je eerst een databaseverbinding maken, vervolgens een recordset maken en tenslotte de gegevens in HTML weergeven?
Een record weergeven in een HTML-tabel
Gegevens van een tabel weergeven in een HTML-tabel
Titel toevoegen aan HTML-tabel
Hoe kan je een titel toevoegen aan een HTML-tabel om de leesbaarheid te verbeteren?
Kleur toevoegen aan HTML-tabel
Hoe kan je de kleur van een HTML-tabel toevoegen om deze aantrekkelijker te maken?

Veldnamen en de waarden van de velden weergeven

We hebben een database genaamd "Northwind" en we willen de gegevens van de tabel "Customers" weergeven (onthoud om het bestand op te slaan met de extensie .asp):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

Veldnamen en de waarden van de velden weergeven in een HTML-tabel

We kunnen ook de gegevens van de tabel "Customers" in een HTML-tabel weergeven met de volgende code:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

Titel toevoegen aan HTML-tabel

Wij willen een titel toevoegen aan deze HTML-tabel, zodat deze leesbaarder wordt:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>