Pengukuran Skrip ADO melalui GetString()

Gunakan metode GetString() untuk mempercepat skrip ASP Anda (untuk menggantikan Response.Write berbaris).

Contoh

Penggunaan GetString()
Bagaimana untuk menggunakan GetString() untuk menampilkan data dalam kumpulan rekaman tabel HTML.

Bersurat berbaris Response.Write

Contoh di bawah ini memperlihatkan cara menampilkan hasil query database dalam tabel HTML:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
      <td><%Response.Write(rs.fields("Companyname"))%></td>
      <td><%Response.Write(rs.fields("Contactname"))%></td>
   </tr>
<%rs.MoveNext
loop%>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

对于一个大型的查询来说，这样做会增加脚本的处理时间，这是由于服务器需要处理大量的 Response.Write 命令。

解决方案是创建全部字符串，从 <table> 到 </table>，然后将其输出 - 只使用一次 Response.Write。

GetString() 方法

GetString() 方法使我们能够仅使用一次 Response.Write 就可以显示所有的字符串。同时它甚至不需要 do..loop 代码以及条件测试来检查记录集是否处于 EOF。

语法

str = rs.GetString(format,rows,coldel,rowdel,nullexpr)

如需使用来自记录集的数据创建一个 HTML 表格，我们只需要使用以上参数中的三个（所有的参数都是可选的）：

  • coldel - 用作列分隔符的 HTML
  • rowdel - 用作行分隔符的 HTML
  • nullexpr - 当列为空时所使用的 HTML

注释：GetString() 方法是 ADO 2.0 的特性。您可以从以下地址下载 ADO 2.0：http://www.microsoft.com/data/download.htm

在以下的例子中，我们将使用 GetString() 方法，把记录集存为一个字符串：

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
str=rs.GetString(,,"</td><td>","</td></tr><tr><td>"," ")
%>
<table border="1" width="100%">
  <tr>
    <td><%Response.Write(str)%></td>
  </tr>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

Variabel str di atas mengandungi satu string bagi semua kolom dan baris yang diembalikkan oleh pernyataan SELECT. Di antara setiap kolom akan muncul </td><td>, dan di antara setiap baris akan muncul </td></tr><tr><td>. Dengan menggunakan Response.Write sekali, kami mendapatkan HTML yang diperlukan.