ADO 표시

기록 집에서 데이터를 표시하는 가장 일반적인 방법은 데이터를 HTML 테이블에 표시하는 것입니다.

예제

기록 표시
먼저 데이터베이스 연결을 만들고, 그 다음 기록 집을 만들고, 그 중 데이터를 HTML에 표시하는 방법.
HTML 테이블에 기록 표시
데이터 테이블의 데이터를 HTML 테이블에 표시하는 방법.
HTML 테이블에 제목 추가
HTML 테이블에 제목을 추가하여 더 읽기 쉬운 것으로 만들어야 하는 방법.
HTML 테이블에 색상 추가
HTML 테이블에 색상을 추가하여 더 아름다운 것으로 만들어야 하는 방법.

필드 이름과 필드 값을 표시

"Northwind" 데이터베이스가 있으며, "Customers" 테이블의 데이터를 표시하고자 합니다. (이 파일을 저장할 때 확장자를 .asp로 설정하십시오):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

필드 이름과 필드 값을 HTML 테이블에 표시

아래 코드를 통해 "Customers" 테이블의 데이터를 HTML 테이블에 표시할 수도 있습니다:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

HTML 테이블에 제목 추가

이 HTML 테이블에 제목을 추가하고자 합니다. 이렇게 하면 더 읽기 쉬워집니다:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>