एडीओ डिस्प्ले

रिकॉर्डसेट से डाटा दिखाने के सबसे आम तरीका डाटा को HTML तालिका में दिखाना है。

उदाहरण

रिकॉर्ड दिखाएं
कैसे पहले डाटाबेस कनेक्शन बनाएं, फिर रिकॉर्डसेट बनाएं और फिर उसमें डाटा HTML में दिखाएं?
HTML तालिका में रिकॉर्ड दिखाएं
कैसे डाटा तालिका के डाटा को HTML तालिका में दिखाएं?
HTML तालिका में शीर्षक जोड़ें
कैसे HTML तालिका को शीर्षक जोड़कर इसे पढ़ाया जा सके?
HTML तालिका में रंग जोड़ें
कैसे HTML तालिका को रंग जोड़कर इसे सुंदर बनाएं?

क्षेत्र नाम और क्षेत्र मूल्य दिखाएं

हमें एक नाम "Northwind" डाटाबेस है और हम "Customers" तालिका के डाटा को दिखाना चाहते हैं (इस फ़ाइल को .asp एक्सटेंशन से सहेजें):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

एक HTML तालिका में क्षेत्र नाम और क्षेत्र के मूल्य दिखाएं

हम इस कोड से भी "Customers" तालिका के डाटा को HTML तालिका में दिखा सकते हैं:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

HTML तालिका में शीर्षक जोड़ें

हम इस HTML तालिका में एक शीर्षक जोड़ना चाहते हैं ताकि यह अधिक पढ़ाया जा सके:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>