Εμφάνιση ADO

Η πιο συχνά χρησιμοποιούμενη μέθοδος εμφάνισης δεδομένων από ένα σύνολο εγγραφών είναι η εμφάνιση των δεδομένων σε μια HTML τάβλη.

Παράδειγμα

Εμφάνιση εγγραφών
Πώς να δημιουργήσεις μια σύνδεση βάσης δεδομένων, να δημιουργήσεις ένα σύνολο εγγραφών και να εμφανίσεις τα δεδομένα σε HTML.
Εμφάνιση των εγγραφών στην HTML τάβλη
Πώς να εμφανίσεις τα δεδομένα μιας τάβλης δεδομένων σε μια HTML τάβλη.
Προσθήκη τίτλου στην HTML τάβλη
Πώς να προσθέσεις τίτλο σε μια HTML τάβλη για να την κάνεις πιο αναγνωρίσιμη.
Προσθήκη χρώματος στην HTML τάβλη
Πώς να προσθέσεις χρώμα σε μια HTML τάβλη για να την κάνεις πιο όμορφη.

Εμφάνιση των ονομάτων των πεδίων και των τιμών των πεδίων

Έχουμε μια βάση δεδομένων με το όνομα "Northwind" και θέλουμε να εμφανίσουμε τα δεδομένα της τάβλης "Customers" (θυμήσου να αποθηκεύσεις το αρχείο με την επέκταση .asp):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

Εμφάνιση των ονομάτων των πεδίων και των τιμών των πεδίων σε μια HTML τάβλη

Μπορούμε επίσης να χρησιμοποιήσουμε τον παρακάτω κώδικα για να εμφανίσουμε τα δεδομένα της τάβλης "Customers" σε μια HTML τάβλη:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

Προσθήκη τίτλου στην HTML τάβλη

Ελπίζουμε να προσθέσουμε ένα τίτλο σε αυτήν την HTML τάβλη, ώστε να γίνει πιο εύκολα αναγνωρίσιμη:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>