ADO প্রদর্শন

রেকর্ডসেট থেকে ডাটা দেখানোর সবচেয়ে সাধারণ পদ্ধতি হল তা HTML টেবিলে দেখানো

উদাহরণ

রেকর্ড দেখানো
কিভাবে প্রথমে একটি ডাটাবেস কানেকশন তৈরি করা, তারপর একটি রেকর্ডসেট তৈরি করা এবং তারপর তার ডাটা HTML-এ দেখানো হোক。
HTML টেবিলে রেকর্ড দেখানো
কিভাবে ডাটা টেবিলের ডাটা HTML টেবিলে দেখানো যায়。
HTML টেবিলে শিরোনাম যোগ করা
কিভাবে HTML টেবিলে শিরোনাম যোগ করে এটা আরও পড়ায় সহজ করা যায়。
HTML টেবিলে রঙ যোগ করা
কিভাবে HTML টেবিলে রঙ যোগ করে এটা আরও সুন্দর করা যায়。

ফিল্ড নাম এবং ফিল্ড মান দেখানো

আমাদের একটি "Northwind" নামের ডাটাবেস আছে, এবং আমরা চাই যে "Customers" টেবিলের ডাটা দেখানো হোক (মনে রাখুন, .asp এক্সটেনশনে ফাইল সংরক্ষণ করুন):

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT * FROM Customers", conn
do until rs.EOF
  for each x in rs.Fields
    Response.Write(x.name)
    Response.Write(" = ")
    Response.Write(x.value & "<br />") 
  next
  Response.Write("<br />")
  rs.MoveNext
loop
rs.close
conn.close
%>
</body>
</html>

একটি HTML টেবিলে ফিল্ড নাম এবং ফিল্ড মান দেখানো

আমরা একইভাবে নিচের কোডটি দিয়ে "Customers" টেবিলের ডাটা একটি HTML টেবিলে দেখাতে পারি:

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
   <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
   <%next
   rs.MoveNext%>
   </tr>
<%loop
rs.close
conn.close
%>
</table>
</body>
</html>

HTML টেবিলে শিরোনাম যোগ করা

আমরা এই HTML টেবিলে শিরোনাম যোগ করতে চাই, যাতে তা আরও পড়ায় সহজ হয়

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
sql="SELECT Companyname, Contactname FROM Customers"
rs.Open sql, conn
%>
<table border="1" width="100%">
  <tr>
  <%for each x in rs.Fields
    response.write("<th>" & x.name & "</th>")
  next%>
  </tr>
  <%do until rs.EOF%>
    <tr>
    <%for each x in rs.Fields%>
      <td><%Response.Write(x.value)%></td>
    <%next
    rs.MoveNext%>
    </tr>
  <%loop
  rs.close
  conn.close
  %>
</table>
</body>
</html>