كوكي ASP

الـكوكي تستخدم غالبًا لتحديد هوية المستخدم.

مثال

الكوكي الترحيب
كيفية إنشاء كوكي ترحيب.

ما هو الكوكي؟

الـكوكي تستخدم غالبًا لتحديد هوية المستخدم. الكوكي هو ملف صغير يتركه الخادم على جهاز المستخدم. كلما طلب جهاز كمبيوتر واحد من خلال المتصفح صفحة، كان هذا الجهاز يرسل الكوكي أيضًا. من خلال ASP، يمكنك إنشاء واسترجاع قيمة الكوكي.

كيف يمكنني إنشاء كوكي؟

"Response.Cookies" أمر يستخدم لإنشاء الكوكي.

ملاحظة:يجب أن يكون أمر "Response.Cookies" قبل علامة <html>.

في المثال التالي، سنقوم بإنشاء كوكي تُدعى "firstname" ونُسلم له "Alex":

<%
Response.Cookies("firstname")="Alex"
%>

يمكنك أيضًا تعيين خصائص الكوكي، مثل تعيين تاريخ انتهاء صلاحية الكوكي:

<%
Response.Cookies("firstname")="Alex"　
Response.Cookies("firstname").Expires=#May 10,2020#
%>

كيف يمكنني استرداد قيمة الكوكي؟

"Request.Cookies" أمر يستخدم لاسترداد قيمة الكوكي.

في المثال التالي، نحن نعيد استرداد قيمة الكوكي المسمى "firstname" ونعرضها على الصفحة:

<%
fname=Request.Cookies("firstname")
response.write("Firstname=" & fname)
%>

الإخراج:

Firstname=Alex

الكوكي مع المفاتيح

إذا كان الكوكي يحتوي على مجموعة من القيم، يمكننا القول أن الكوكي يحتوي على مفاتيح (Keys).

في المثال التالي، سنقوم بإنشاء مجموعة من الكوكي تُدعى "user". "user" الكوكي يحتوي على مفاتيح تحتوي على معلومات المستخدم:

<%
Response.Cookies("user")("firstname")="John"
Response.Cookies("user")("lastname")="Adams"
Response.Cookies("user")("country")="UK"
Response.Cookies("user")("age")="25"
%>

قراءة جميع الكوكي

يرجى قراءة الكود التالي:

<%
Response.Cookies("firstname")="Alex"
Response.Cookies("user")("firstname")="John"
Response.Cookies("user")("lastname")="Adams"
Response.Cookies("user")("country")="UK"
Response.Cookies("user")("age")="25"
%>

افترض أن خادمك يرسل جميع هذه الكوكي إلى مستخدم معين.

الآن، نحتاج إلى قراءة هذه الكوكي. إليك مثال يوضح كيفية القيام بذلك (لاحظ أن الكود التالي يستخدم HasKeys للتحقق من أن الكوكي يحتوي على مفتاح):

<html>
<body>
<%
dim x,y
 for each x in Request.Cookies
  response.write("<p>")
  if Request.Cookies(x).HasKeys then
    for each y in Request.Cookies(x)
      response.write(x & ":" & y & "="　& Request.Cookies(x)(y))
      response.write("<br />")
    next
  else
    Response.Write(x & "=" & Request.Cookies(x) & "<br />")
  end if
  response.write "</p>"
next
%>
</body>
</html>

الإخراج:

firstname=Alex
user:firstname=John
user:lastname=Adams
user:country=UK
user:age=25

كيفية التعامل مع متصفحات لا تدعم ملفات الـ cookie؟

إذا كان تطبيقك يحتاج إلى التعامل مع متصفحات لا تدعم ملفات الـ cookie، فإنك مجبر على استخدام طرق أخرى لنقل المعلومات بين صفحات تطبيقك. هناك طريقتان:

1. إضافة معلمات إلى URL

يمكنك إضافة معلمات إلى URL:

<a href="welcome.asp?fname=John&lname=Adams">
اذهب إلى صفحة الترحيب
</a>

ثم استعادة هذه القيم في ملف "welcome.asp" مثل التالي:

<%
fname=Request.querystring("fname")
lname=Request.querystring("lname")
response.write("<p>مرحبًا " & fname & " " & lname & "!</p>")
response.write("<p>مرحبًا بك في موقعي!</p>")
%>

2. استخدام النموذج

يمكنك أيضًا استخدام النموذج. عند الضغط على زر التأكيد، سيقوم النموذج بتقديم بيانات المستخدم إلى "welcome.asp":

<form method="post" action="welcome.asp">
First Name:  <input type="text" name="fname" value="">
Last Name: <input type="text" name="lname" value="">
<input type="submit" value="Submit">
</form>

ثم استعادة هذه القيم في ملف "welcome.asp" كما يلي:

<%
fname=Request.form("fname")
lname=Request.form("lname")
response.write("<p>مرحبًا " & fname & " " & lname & "!</p>")
response.write("<p>مرحبًا بك في موقعي!</p>")
%>